Flutter iOS Embedder
VsyncWaiterIOSTest.mm
Go to the documentation of this file.
1 // Copyright 2013 The Flutter Authors. All rights reserved.
2 // Use of this source code is governed by a BSD-style license that can be
3 // found in the LICENSE file.
4 
5 #import <OCMock/OCMock.h>
6 #import <XCTest/XCTest.h>
7 
8 #include <memory>
9 
10 #include "flutter/common/task_runners.h"
11 #include "flutter/fml/message_loop.h"
12 #import "flutter/shell/platform/darwin/ios/InternalFlutterSwift/InternalFlutterSwift.h"
14 
15 namespace {
16 
17 flutter::TaskRunners CreateTestTaskRunners() {
18  fml::MessageLoop::EnsureInitializedForCurrentThread();
19  fml::RefPtr<fml::TaskRunner> task_runner = fml::MessageLoop::GetCurrent().GetTaskRunner();
20  return flutter::TaskRunners("VsyncWaiterIOSTest", task_runner, task_runner, task_runner,
21  task_runner);
22 }
23 
24 } // namespace
25 
26 @interface VsyncWaiterIOSTest : XCTestCase
27 @end
28 
29 @implementation VsyncWaiterIOSTest
30 
31 - (void)testSnapDurationWithValidDuration {
32  // 60Hz: 1/60 = 0.016666...
33  CFTimeInterval duration = 0.016667;
34  CFTimeInterval snapped = flutter::VsyncWaiterIOS::SnapDuration(duration, 60.0);
35  XCTAssertEqualWithAccuracy(snapped, 1.0 / 60.0, 0.0001);
36 
37  // 120Hz: 1/120 = 0.008333...
38  duration = 0.008334;
39  snapped = flutter::VsyncWaiterIOS::SnapDuration(duration, 120.0);
40  XCTAssertEqualWithAccuracy(snapped, 1.0 / 120.0, 0.0001);
41 }
42 
43 - (void)testSnapDurationWithInvalidDuration {
44  // Zero duration should fallback to max_refresh_rate.
45  CFTimeInterval snapped = flutter::VsyncWaiterIOS::SnapDuration(0.0, 120.0);
46  XCTAssertEqualWithAccuracy(snapped, 1.0 / 120.0, 0.0001);
47 
48  // Negative duration should fallback to max_refresh_rate.
49  snapped = flutter::VsyncWaiterIOS::SnapDuration(-0.1, 80.0);
50  XCTAssertEqualWithAccuracy(snapped, 1.0 / 80.0, 0.0001);
51 }
52 
53 - (void)testSnapDurationWithZeroMaxRefreshRateFallback {
54  // If duration is invalid AND max_refresh_rate is 0, fallback to 60Hz.
55  CFTimeInterval snapped = flutter::VsyncWaiterIOS::SnapDuration(0.0, 0.0);
56  XCTAssertEqualWithAccuracy(snapped, 1.0 / 60.0, 0.0001);
57 
58  snapped = flutter::VsyncWaiterIOS::SnapDuration(-1.0, -10.0);
59  XCTAssertEqualWithAccuracy(snapped, 1.0 / 60.0, 0.0001);
60 }
61 
62 - (void)testConstructorUsesInjectedDisplayLinkManagerRefreshRate {
63  id mockDisplayLinkManager = OCMPartialMock([FlutterDisplayLinkManager shared]);
64  [self addTeardownBlock:^{
65  [mockDisplayLinkManager stopMocking];
66  }];
67  double maxFrameRate = 120;
68  (void)[[[mockDisplayLinkManager stub] andReturnValue:@(maxFrameRate)] displayRefreshRate];
69 
70  flutter::TaskRunners taskRunners = CreateTestTaskRunners();
71  auto waiter = std::make_unique<flutter::VsyncWaiterIOS>(taskRunners, mockDisplayLinkManager);
72 
73  XCTAssertEqual(waiter->GetMaxRefreshRateForTesting(), maxFrameRate);
74 }
75 
76 - (void)testAwaitVSyncPicksUpRefreshRateChangesFromInjectedDisplayLinkManager {
77  id mockDisplayLinkManager = OCMPartialMock([FlutterDisplayLinkManager shared]);
78  [self addTeardownBlock:^{
79  [mockDisplayLinkManager stopMocking];
80  }];
81  // A single stub whose return value is re-read on every invocation via the __block variable.
82  // OCMock stubs aren't replaced by re-stubbing the same selector — the first-registered stub
83  // keeps answering — so a fixed andReturnValue: can't model a value that changes over time.
84  double initialFrameRate = 60;
85  __block double refreshRate = initialFrameRate;
86  OCMStub([mockDisplayLinkManager displayRefreshRate]).andDo(^(NSInvocation* invocation) {
87  [invocation setReturnValue:&refreshRate];
88  });
89 
90  flutter::TaskRunners taskRunners = CreateTestTaskRunners();
91  auto waiter = std::make_unique<flutter::VsyncWaiterIOS>(taskRunners, mockDisplayLinkManager);
92  XCTAssertEqual(waiter->GetMaxRefreshRateForTesting(), initialFrameRate);
93 
94  double updatedFrameRate = 120;
95  refreshRate = updatedFrameRate;
96  waiter->AwaitVSync();
97 
98  XCTAssertEqual(waiter->GetMaxRefreshRateForTesting(), updatedFrameRate);
99 }
100 
101 - (void)testAwaitVSyncFromPausedDisplayLinkUsesSyntheticTargetTime {
102  id mockDisplayLinkManager = OCMPartialMock([FlutterDisplayLinkManager shared]);
103  [self addTeardownBlock:^{
104  [mockDisplayLinkManager stopMocking];
105  }];
106  double maxFrameRate = 120;
107  (void)[[[mockDisplayLinkManager stub] andReturnValue:@(maxFrameRate)] displayRefreshRate];
108 
109  flutter::TaskRunners taskRunners = CreateTestTaskRunners();
110  auto waiter = std::make_unique<flutter::VsyncWaiterIOS>(taskRunners, mockDisplayLinkManager);
111 
112  bool fired = false;
113  fml::TimeDelta frameInterval;
114  waiter->SetDispatchingEvent(true);
115  waiter->AsyncWaitForVsync([&](std::unique_ptr<flutter::FrameTimingsRecorder> recorder) {
116  fired = true;
117  frameInterval = recorder->GetVsyncTargetTime() - recorder->GetVsyncStartTime();
118  });
119  waiter->SetDispatchingEvent(false);
120  fml::MessageLoop::GetCurrent().RunExpiredTasksNow();
121 
122  XCTAssertTrue(fired);
123  XCTAssertGreaterThan(frameInterval.ToNanoseconds(), 0);
124  XCTAssertEqualWithAccuracy(frameInterval.ToSecondsF(), 1.0 / maxFrameRate, 0.0001);
125 }
126 
127 - (void)testAwaitVSyncFromPausedDisplayLinkWhenNotDispatchingEvent {
128  id mockDisplayLinkManager = OCMPartialMock([FlutterDisplayLinkManager shared]);
129  [self addTeardownBlock:^{
130  [mockDisplayLinkManager stopMocking];
131  }];
132  double maxFrameRate = 120;
133  (void)[[[mockDisplayLinkManager stub] andReturnValue:@(maxFrameRate)] displayRefreshRate];
134 
135  flutter::TaskRunners taskRunners = CreateTestTaskRunners();
136  auto waiter = std::make_unique<flutter::VsyncWaiterIOS>(taskRunners, mockDisplayLinkManager);
137 
138  bool fired = false;
139  XCTestExpectation* expectation = [self expectationWithDescription:@"display link callback"];
140  waiter->AsyncWaitForVsync([&](std::unique_ptr<flutter::FrameTimingsRecorder> recorder) {
141  fired = true;
142  [expectation fulfill];
143  });
144  fml::MessageLoop::GetCurrent().RunExpiredTasksNow();
145 
146  XCTAssertFalse(fired);
147  [self waitForExpectationsWithTimeout:5.0 handler:nil];
148  XCTAssertTrue(fired);
149 }
150 
151 @end
static CFTimeInterval SnapDuration(CFTimeInterval duration, double max_refresh_rate)
FlutterFMLTaskRunners * CreateTestTaskRunners(NSString *label)